Afin de pouvoir faire un backup différentiel sur disque (au lieu de bandes) et d'avoir un rollup automatique sur 3 générations on peut faire un script de cmd, par exemple: zbackupdif.cmd avec ceci:

----------

rem zf ver 0.3   19:21 19-Oct-03
rem zbackupdif, permet d'utiliser le NTbackup pour faire un backup diff avec rollup de backup sur disque
rem Utilisation:
rem arg1: fichier de selection du backup *.bks, ATTENTION toujours avec des ""
rem arg2: path de destination pour le fichier du backup, ATTENTION toujours avec des "" et SANS \ final
rem arg3: fichier destination pour le backup *.bkf, ATTENTION toujours avec des ""

set f1=%1
set p2=%2
set f2=%3

rem lui enleve le " au debut (1 car au debut)
set p2=%p2:~1%
rem lui enleve le " a la fin (1 car a la fin)
set p2=%p2:~0,-1%

rem lui enleve le " au debut (1 car au debut)
set f2=%f2:~1%
rem lui enleve le " a la fin (1 car a la fin)
set f2=%f2:~0,-1%

rem fabrique le nom de fichier complet avec le \ les " de debut et fin
set f3="%p2%\%f2%"

rem fabrique le label de la bande
set label="Set created %date% at %time%"

ntbackup.exe backup %f1% /a /d %label% /v:no /r:no /rs:no /hc:off /m differential /j "Bkp Diff Datas" /l:s /f %f3%

rem cree le rollup
del "%p2%\%f2%_moins_3"
rename "%p2%\%f2%_moins_2" "%f2%_moins_3"
rename "%p2%\%f2%_moins_1" "%f2%_moins_2"
rename %f3% "%f2%_moins_1"

----------

puis de l'utiliser avec cela:

zbackupdif "@F:\Documents and Settings\papa.crissier\Local Settings\Application Data\Microsoft\Windows NT\NTBackup\data\test bkp dif.bks" "K:\Backup\papa\Datas\d030919" "zd030919.bkf"

ou ça: (même chose)

E:\winh\zbackupdif.cmd "@E:\Documents and Settings\rootzf.SERVERS\Local Settings\Application Data\Microsoft\Windows NT\NTBackup\data\data.bks" "F:\Backup\Data\d031031" "d031031.bkf"

que l'on peut mettre très facilement dans un wintask avec une échance journalière ou hebdomadaire...